range de lignes de longueur variable

Bonjour MLagrange,

Voici le code que je te propose (un peu remanié) :

Sub Convers()

'Nettoyage de la feuille reclassement
With Sheets("Reclassement")
    .Activate
    'Tableau structuré > Plage - Il faut évidemment qu'un tableau structuré existe avec le nom DATA
    .ListObjects("DATA").Unlist
    'Trouver la dernière ligne de la feuille Reclassement
    DernLigR = .Range("A" & Rows.Count).End(xlUp).Row
    'Suppression des anciennes lignes pour faire de la place
    'Le test '1' : pour être certain que le tableau contient des données sinon il efface la ligne des titres
    If DernLigR > 1 Then .Range("A2:J" & DernLigR).EntireRow.Delete
End With

'Copie des données Conversion > Reclassement
With Sheets("Conversion")
    .Activate
    'Trouver la dernière ligne de Conversion
    DernLigC = .Range("A" & Rows.Count).End(xlUp).Row
    'Copie des données de Conversion > Reclassement
    .Range("A2:A" & DernLigC).Copy Sheets("Reclassement").Range("A2")
    Application.CutCopyMode = False
End With
    
With Sheets("Reclassement")
    .Activate
    .Range("A2:A" & DernLigC).Select
    'Conversion de la colonne A en différentes colonnes
    Selection.TextToColumns Destination:=Sheets("Reclassement").Range("A2"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=True, Space:=False, Other:=False, FieldInfo _
        :=Array(Array(1, 1), Array(2, 1), Array(3, 1), Array(4, 1), Array(5, 1), Array(6, 1), _
        Array(7, 1), Array(8, 1), Array(9, 1), Array(10, 1)), TrailingMinusNumbers:=True
    'Suppression des doublons
    .Range("$A$1:$J$" & DernLigC).RemoveDuplicates Columns:=1, Header:=xlYes
'Mise en forme des données
    DernLigR = .Range("A" & Rows.Count).End(xlUp).Row
    .Range("B2:B" & DernLigR).Select
    Selection.NumberFormat = "yyyy/mm/dd hh:mm:ss"
    .Range("C2:C" & DernLigR).Select
    Selection.NumberFormat = "mm/dd/yyyy"
    .Range("H2:H" & DernLigR).Select
    Selection.NumberFormat = "0.00000"
    .Range("I2:I" & DernLigR).Select
    Selection.NumberFormat = "#,##0.00 $"

'Mettre en tableau structuré
    Set myTable = .Range("A2").CurrentRegion
    .ListObjects.Add(xlSrcRange, myTable, , xlYes).Name = "DATA"
    .ListObjects("DATA").TableStyle = "TableStyleLight9"

'Tri du tableau
    With .ListObjects("DATA").Sort
        .SortFields.Clear
        'Mise en place des trois clés de tri
        .SortFields.Add Key:=Range("DATA[Date]"), SortOn:=xlSortOnValues, Order:=xlAscending _
            , DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("DATA[Titre]"), SortOn:=xlSortOnValues, Order:=xlAscending _
            , DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("DATA[Heure/min]"), SortOn:=xlSortOnValues, Order:= _
            xlAscending, DataOption:=xlSortNormal
        'Tri effectif
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
'Ajuster les colonnes
    .Columns("A:J").Select
    .Columns("A:J").EntireColumn.AutoFit

End With
End Sub