Re-,
Sorry, j’ai mis ‘mm’ au lieu de ‘nn’

Option Explicit
Sub Welcome()

Dim QuelleHeure As Byte
Dim QuelleMinute As Byte
Dim Intro As String, Heu As String, Min As String

QuelleHeure = Format(Now(), "hh")
If QuelleHeure > 1 Then Heu = "Heures" Else Heu = "Heure"
If QuelleHeure >= 18 Then Intro = "Bonsoir" Else Intro = "Bonjour"
QuelleMinute = Format(Now(), "nn")
If QuelleMinute > 1 Then Min = "Minutes" Else Min = "Minute"
MsgBox Intro & ", nous sommes le " & Format(Date, "dddd d mmmm yyyy") & _
 Chr(10) & "et il est " & QuelleHeure & " " & Heu & " et " & QuelleMinute & " " & Min & "."
End Sub

Pour info, si tu veux connaître les détails de Now

Sub TestDate()
    MsgBox Format(Now(), "dd")
    MsgBox Format(Now(), "mm")
    MsgBox Format(Now(), "yyyy")
 
    MsgBox Format(Now(), "hh")
    MsgBox Format(Now(), "nn")
    MsgBox Format(Now(), "ss")
End Sub

Bonsoir Pimpin,
Comment cela fonctionne avec le VBA. Voici un petit code qui te prmettra d’avoir un pop-up avec le message désiré. Après, il te restera à la mettre dans tes cellules au bon endroit.

Option Explicit
Sub Welcome()

Dim QuelleHeure As Byte
Dim QuelleMinute As Byte
Dim Intro As String, Heu As String, Min As String

QuelleHeure = Format(Now(), "hh")
If QuelleHeure > 1 Then Heu = "Heures" Else Heu = "Heure"
If QuelleHeure >= 18 Then Intro = "Bonsoir" Else Intro = "Bonjour"
QuelleMinute = Format(Now(), "mm")
If QuelleMinute > 1 Then Min = "Minutes" Else Min = "Minute"
MsgBox Intro & ", nous sommes le " & Format(Date, "dddd d mmmm yyyy") & _
 Chr(10) & "et il est " & Format(Now(), "hh") & " " & Heu & " et " & Format(Now(), "mm") & " " & Min & "."
End Sub

Pour le question 2 :
Pour le mot de passe tu peux utiliser ce codes.

Code 1 : à mettre dans ThisWorkbook. Donc, à l’ouverture du fichier, on te demande ton MDP qui est ‘Test’. Si c’est correct, tu continues, sinon Excel se ferme.

Private Sub Workbook_Open()
    Dim PASSWORD As String, MDP
    PASSWORD = "Test"
    MDP = InputBoxDmdMDP("Entrez le mot de passe...", "Password")
    If MDP <> PASSWORD Then
        MsgBox ("L'accès ne vous est pas autorisé. Bye Bye ! ")
        Application.Quit
    End If
End Sub

Code 2 : à mettre dans la partie Modules. Cette partie permet de gérer les *.

Option Explicit
Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long
Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" _
(ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _
ByVal dwThreadId As Long) As Long
Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long
Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" _
(ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long
Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0
Private hHook As Long

Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim RetVal
Dim strClassName As String, lngBuffer As Long
If lngCode < HC_ACTION Then
    NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
    Exit Function
End If
strClassName = String$(256, " ")
lngBuffer = 255
 If lngCode = HCBT_ACTIVATE Then
    RetVal = GetClassName(wParam, strClassName, lngBuffer)
        If Left$(strClassName, RetVal) = "#32770" Then
        SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
        End If
 End If
CallNextHookEx hHook, lngCode, wParam, lParam
End Function

Public Function InputBoxDmdMDP(Prompt, Optional Title, Optional Default, Optional XPos, _
Optional YPos, Optional HelpFile, Optional Context) As String
Dim lngModHwnd As Long, lngThreadID As Long
lngThreadID = GetCurrentThreadId
lngModHwnd = GetModuleHandle(vbNullString)
hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)
InputBoxDmdMDP = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
UnhookWindowsHookEx hHook
End Function

• Cette réponse a été modifiée le il y a 3 années et 9 mois par Lionel.

Salut,
Voici ce que je te propose. La méthode Find devrait être plus rapide que passer toutes les cellules en revue (le fichier est en xslx, à modifier en xlsm pour activer les macros) :

Option Explicit

Sub Find_And_Delete()

Dim LigneASuppr As Range, PlageDeRecherche As Range
Dim Valeur_Cherchee As String, AdresseTrouvee As String

Valeur_Cherchee = InputBox("Référence à supprimer")
'Dans la première colonne de la feuille BDD
Set PlageDeRecherche = Sheets("BDD").Range("A:A")
'*******************************

'Méthode find, ici on cherche la valeur exacte (LookAt:=xlWhole)
Set LigneASuppr = PlageDeRecherche.Cells.Find(what:=Valeur_Cherchee, LookAt:=xlWhole)

'Traitement de l'erreur possible : Si on ne trouve rien :
If LigneASuppr Is Nothing Then
    'Ici, traitement pour le cas où la valeur n'est pas trouvée
    AdresseTrouvee = Valeur_Cherchee & " n'est pas présent dans " & PlageDeRecherche.Address
    MsgBox AdresseTrouvee
Else
    'Ici, traitement pour le cas où la valeur est trouvée
    AdresseTrouvee = Range(LigneASuppr.Address).Row
    Rows(AdresseTrouvee).Delete
    MsgBox "La ligne " & AdresseTrouvee & " avec la référence " & Valeur_Cherchee & " a été supprimée."
End If

'Vidage des variables
Set PlageDeRecherche = Nothing
Set LigneASuppr = Nothing
End Sub

• Cette réponse a été modifiée le il y a 3 années et 9 mois par Lionel.

Salut Pimpin,
(⊙﹏⊙)
Avec une simple formule, tu ne peux pas supprimer une ligne de ta DB. Tu peux trouver le numéro de ligne mais ensuite, soit tu le fais en manuel soit via VBA. De plus, juste effacer le contenu risque de te poser un problème car tu vas avoir des lignes vides au fur et à mesure dans ta DB ce qui n’est pas très logique, ni performant…

Bonjour,
Je n’en sais pas assez pour répondre d’une manière précise. Je te propose ce fichier avec deux possibilités : si tes données sont triées sur les Directeurs (tableau de gauche) si tes données ne sont pas triées (tableau de droite).

Salut Pimpin,
À ma connaissance, ce n’est pas possible d’appliquer un formatage (gras, souligner, couleur ou autre) au résultat d’une partie d’une formule.

Bonjour,
En C2, tu peux essayer cette formule :
=SI(OU(ET(A2>=0;B2>=0);ET(A2<=0;B2<=0));B2-A2;B2+A2)
est-ce que cela colle pour tous tes cas (négatif et positif) ?

• Cette réponse a été modifiée le il y a 3 années et 10 mois par Lionel.